読者です 読者をやめる 読者になる 読者になる

B-Teck!

お仕事からゲームまで幅広く

【VBA】配列をソートする

VBA
'/**
' * quickSort
' * 配列をクイックソートする
' * 大小比較できる型ならとりあえずソートできるはず
' * @param  Variant       aryVal sort対象配列
' * @param  Optional Long left   sort範囲左
' * @param  Optional Long right  sort範囲右
' * @return sort後配列
' */
Sub quickSort(ByRef aryVal As Variant, Optional ByVal left As Long = -1, _
                                       Optional ByVal right As Long = -1)
    Dim l As Long
    Dim r As Long
    Dim pivot As Variant
    Dim tmp As Variant

    If left = -1 Or right = -1 Then
        left = LBound(aryVal)
        right = UBound(aryVal)
    End If
    
    l = left
    r = right
    'ソート範囲の中央の値を取得
    pivot = aryVal(Int((left + right) / 2))
    
    Do
        '配列の先頭から、中央の値より大きいものを探す
        Do While aryVal(l) < pivot
            l = l + 1
        Loop
        '配列の末尾から、中央の値より小さいものを探す
        Do While aryVal(r) > pivot
            r = r - 1
        Loop
        
        'ソートの必要がなければループ終了
        If l >= r Then Exit Do
        
        '前半部の大きい値と後半部の小さい値を入れ替える
        tmp = aryVal(l)
        aryVal(l) = aryVal(r)
        aryVal(r) = tmp
        
        l = l + 1
        r = r - 1
    Loop
    
    'ソートが終わるまで再帰的に自分を呼び出し
    If (left < l - 1) Then
        Call quickSort(aryVal, left, l - 1)
    End If
    
    If (right > r + 1) Then
        Call quickSort(aryVal, r + 1, right)
    End If
End Sub

'/**
' * bubbleSort
' * 配列をバブルソートする
' * 大小比較できる型ならとりあえずソートできるはず
' * @param  aryVal sort対象配列
' * @return sort後配列
' */
Sub bubbleSort(ByRef aryVal As Variant)
    Dim i As Long
    Dim j As Long
    Dim tmp As Variant
    
    For i = 0 To UBound(aryVal)
        For j = UBound(aryVal) To i Step -1
            If aryVal(i) > aryVal(j) Then
                tmp = aryVal(i)
                aryVal(i) = aryVal(j)
                aryVal(j) = tmp
            End If
        Next j
    Next i
End Sub
'テスト用
Sub test()

    Dim aryQuick() As Variant: ReDim aryQuick(0)
    Dim aryBubble() As Variant: ReDim aryBubble(0)
    Dim i As Long
    '乱数で配列生成
    For i = 0 To 10000
        ReDim Preserve aryQuick(UBound(aryQuick) + 1)
        aryQuick(UBound(aryQuick)) = Int(Rnd * 10000)
        
        ReDim Preserve aryBubble(UBound(aryBubble) + 1)
        aryBubble(UBound(aryBubble)) = Int(Rnd * 10000)
    Next i
    
    'クイックソート開始
    Debug.Print Now()
    Call quickSort(aryQuick)
    'クイックソート終了
    'バブルソート開始
    Debug.Print Now()
    Call bubbleSort(aryBubble)
    'バブルソート終了
    Debug.Print Now()
End Sub